rss feed

by ~migrev-dolseg

this hawk file fetches an RSS (or Atom) feed and turns it into an interface.

screenshot of rss feed

if the feed is a...

youtube channel, a video embed will be shown
podcast, an audio player will be shown
blog, an iframe to the post will be embedded

below, you can copy the code into your hawk

!:
|^
  :-  %shed
  =/  m  (strand ,vase)
  ?.  try-fetch  (pure:m !>((print ~)))
  ::
  ;<  entries=marl  bind:m
    %-  query-feed
    (scut (need (peek /url)))
  %-  pure:m  !>
  (print entries)
  ::
++  print
  ::
  |=  entries=marl
  ;div.page
    ;+  controls
    ;div#entries.p2.fc.g2.mt1
      ;*  entries
    ==
  ==
  ::
++  controls
  ^-  manx  :: the top control form
  =;  m=manx
    ?:  try-fetch  m
    m(a.g [[%open ""] a.g.m])
  ;details.br1.bd1.b1
    ;summary.b2.hover.br1.bd1.p3.frw.jb.ac
      ;h2
        ;+  ;/
        %-  scup
        %+  fall
          (peek /title)
        ta/'rss feed'
      ==
      ;div.f4: {?:(try-fetch "edit feed" "create")}
    ==
    ;+  form
  ==
++  try-fetch
  ^-  ?  :: does the info required for a fetch exist?
  ^~
  ?&  ?=(^ (peek /title))
      ?=(^ (peek /url))
  ==
++  query-feed
  |=  [url=cord]
  =/  m  (strand ,marl)
  ^-  form:m
  =/  =task:iris  [%request [%'GET' url ~ ~] 0 0]
  =/  =card:agent:gall  [%pass /http-req %arvo %i task]
  ;<  ~  bind:m  (send-raw-card card)
  ;<  res=(pair wire sign-arvo)  bind:m  take-sign-arvo
  |=  tin=strand-input:strand
  ::
  :+  ~  %done
  ?.  ?=([%iris %http-response %finished *] q.res)
    ;=
      ;div.f-1: error %bad-sign
    ==
  ::
  =/  status  status-code.response-header.client-response.q.res
  ::
  ?~  full-file.client-response.q.res
    ;=
      ;div.f-1: error %no-body
    ==
  ?:  (gte status 500)
    ;=
      ;div.f-1: urbit error
    ==
  ?:  (gte status 400)
    ;=
      ;div.f-1: network or http error
    ==
  ::
  =/  raw  `@t`q.data.u.full-file.client-response.q.res
  ?~  parsed=(de-xml:html raw)
    ;=
      ;div.f-1: error %invalid-xml-rss
    ==
  ::
  (feed-to-ui u.parsed)
  ::
++  feed-to-ui
  |=  man=manx
  =,  mq
  ^-  marl
  ?:  =(%rss n.g.man)
    ::  rss
    %+  turn
      %+  swag
        :-  +:(fall (peek /start) ud/0)
        +:(fall (peek /count) ud/10)
      %+  skim  (children c.man)
      |=  =manx
      =(%item n.g.manx)
    |=  m=manx
    %:  print-entry
      (as-tape (first-tag %title ~[m]))
      (as-tape (first-tag %link ~[m]))
      :-  ~
      %^    nth-or
          0
        ""
      (attributes %url (first-tag %enclosure ~[m]))
      %-  parse-rfc822-date
      (as-tape (first-tag %'pubDate' ~[m]))
    ==
    ::
  ::  atom
  %+  turn
    %+  swag
      :-  +:(fall (peek /start) ud/0)
      +:(fall (peek /count) ud/10)
    %+  skim  c.man
    |=  =manx
    =(%entry n.g.manx)
  |=  m=manx
  %:  print-entry
    (as-tape (first-tag %title ~[m]))
    %^    nth-or
        0
      ""
    (attributes %href (first-tag %link ~[m]))
    ~
    %-  parse-iso-date
    %-  as-tape
    %+  welp
      (first-tag %'published' ~[m])
    (first-tag %'updated' ~[m])
  ==
  ::
++  print-entry
  ::
  |=  [title=tape link=tape enclosure=(unit tape) date=tape]
  ;details.br1.bd1
    ;summary.fc.p2.b1.hover.br1.bd1
      ;div.s1: {(cass title)}
      ;div.fr.ac.jb.f3
        ;div: {(scup (need (peek /title)))}
        ;div.mono.s-1.date: {date}
      ==
    ==
    ;div.p2.fc.g2
      ;a.f-4
        =target  "_blank"
        =href  link
        ; {link}
      ==
      ;+
      ?+    (fall (peek /type) tas/%blog)
          ;/("")
        [* %video]
          =/  vid  (swag [32 11] link)
          ;iframe.wf.bd1.b3
            =width  "560"
            =height  "315" 
            =loading  "lazy"
            =src  "https://www.youtube.com/embed/{vid}"
            =allow  "accelerometer; autoplay; clipboard-write; encrypted-media; gyroscope; picture-in-picture"
            =allowfullscreen  ""
            ;
          ==
        [* %audio]
          ?~  enclosure
            ;div: no media given
          ;audio(controls "", preload "none")
            ;source(src u.enclosure);
          ==
      ==
    ==
  ==
  ::
++  peek
  ::
  |=  pax=path
  ^-  (unit dime)
  ?^  x=(reb:c pax)  x
  =,  mq
  %+  mong  0
  %-  dimes
  %+  attributes  %value
  (first-attribute %name (spud pax) ~[dat:f])
  ::
++  scut
  ::
  |=  dim=dime
  ?+  p.dim  (scot dim)
    %t   (woad q.dim)
    %ta  (woad q.dim)
  ==
  ::
++  scup
  ::
  |=  dim=dime
  (trip (scut dim))
  ::
++  form
  ::
  ;form.fc.g4.p3.b1.br2.af
    =method  "post"
    :::
    ;+  %+  label  "title"
    =;  m=manx
      ?~  p=(peek /title)  m
      m(a.g [[%value (scow u.p)] a.g.m])
    ;spine-input-atom.br1.bd1.p-1
      =name  "/title"
      =aura  "ta"
      =required  ""
      =placeholder  "feed title"
      ;
    ==
    ::
    ;+  %+  label  "feed url"
    =;  m=manx
      ?~  p=(peek /url)  m
      m(a.g [[%value (scow u.p)] a.g.m])
    ;spine-input-atom.br1.bd1.p-1
      =name  "/url"
      =aura  "ta"
      =required  ""
      =placeholder  "rss feed url"
      ;
    ==
    ::
    ;+
    =/  selected  +:(fall (peek /type) tas/%blog)
    %+  label  "feed type"
    ;select.br1.bd1.p-1
      =name  "/type"
      =required  ""
      =value  (trip selected)
      ;*
      %+  turn  `(list term)`~[%video %audio %blog]
      |=  =term
      =;  o=manx
        ?.  =(term selected)  o
        o(a.g [[%selected ""] a.g.o])
      ;option(value (trip term)): {(trip term)}
    ==
    ::
    ;div.fr.g2
      ;+  %+  label  "range start"
      ;spine-input-atom.br1.bd1.p-1.grow
        =aura  "ud"
        =name  "/start"
        =required  ""
        =min  "0"
        =value  (scow (fall (peek /start) ud/0))
        ;
      ==
      ;+  %+  label  "range count"
      ;spine-input-atom.br1.bd1.p-1.grow
        =aura  "ud"
        =name  "/count"
        =required  ""
        =min  "0"
        =value  (scow (fall (peek /count) ud/10))
        ;
      ==
    ==
    ::
    ;button.p2.mono.loader.b2.hover.br1.bd1.wfc
      ;span.loaded: save
      ;span.loading: ====
    ==
  ==
  ::
++  label
  ::
  |=  [lab=tape =manx]
  ;label.fc.wf
    ;span.mono.p1.s-1.f4: {lab}
    ;+  manx
  ==
  ::
++  parse-iso-date
  ::
  |=  in=tape
  ^-  tape
  =/  yar  (ni:dejs:format n+(crip (swag [0 4] in)))
  =/  month  (ni:dejs:format n+(crip (swag [5 2] in)))
  =/  day  (ni:dejs:format n+(crip (swag [8 2] in)))
  =/  da  (year [[%.y yar] month t=[day 0 0 0 ~[0x0]]])
  (scow %da da)
  ::
++  parse-rfc822-date
  ::
  |=  in=tape
  =/  day  (ni:dejs:format n+(crip (swag [5 2] in)))
  =/  mo  (swag [8 3] in)
  =/  month
    ?:  =(mo "Jan")  1
    ?:  =(mo "Feb")  2
    ?:  =(mo "Mar")  3
    ?:  =(mo "Apr")  4
    ?:  =(mo "May")  5
    ?:  =(mo "Jun")  6
    ?:  =(mo "Jul")  7
    ?:  =(mo "Aug")  8
    ?:  =(mo "Sep")  9
    ?:  =(mo "Oct")  10
    ?:  =(mo "Nov")  11
    ?:  =(mo "Dec")  12
    !!
  =/  yar  (ni:dejs:format n+(crip (swag [12 4] in)))
  =/  da  (year [[%.y yar] month t=[day 0 0 0 ~[0x0]]])
  (scow %da da)
--
::
::
::
::